Hướng dẫn giải bài tập ứng dụng hàm FIND hàm SEARCH chi tiết nhất

Trong bài viết hướng dẫn chi tiết cách sử dụng hàm FIND và SEARCH có bài tập kèm theo, chúng ta đã được tìm hiểu về hàm FIND và hàm SEARCH trong Excel rồi. Đồng thời tại bài viết này có 1 bài tập ứng dụng 2 hàm này trong thực tế. Bạn có tự làm được ra kết quả không? Nếu không hãy tham khảo hướng dẫn cách giải bài tập dưới dây của Gitiho nhé.

Link tải bài tập có thể tải trong bài viết trước, hoặc bạn tải bài tập kèm theo đáp án ở đường link phía cuối bài viết này.

Giải bài tập tách tên Quận, Thành phố từ cột Địa chỉ bằng hàm FIND

Trong bài tập tách tên quận, thành phố từ cột địa chỉ, chúng ta có:

 

Yêu cầu thứ 1: Tách tên Quận

Bước 1: Việc đầu tiên là bạn cần xác định vị trí các dấu phẩy trong các ô tại cột Địa chỉ (cột B)

Cách xác định là chúng ta dùng hàm FIND hoặc hàm SEARCH đều được. Trong bài này chúng ta sẽ dùng hàm FIND. Trước khi viết hàm, bạn cần xác định 3 thành phần trong hàm, lần lượt trả lời các câu hỏi sau đây:

• Tìm cái gì dấu phẩy. Khi viết dấu này phải đặt trong cặp dấu nháy kép ","
• Tìm ở đâu? tại từng ô trong cột Địa chỉ
• Tìm từ vị trí thứ mấy? để tìm dấu phẩy đầu tiên thì sẽ không cần quy định vị trí (tức là tìm từ vị trí ký tự đầu tiên trở đi), còn dấu phẩy thứ hai sẽ tìm từ sau vị trí dấu phẩy thứ 1 trở đi.

Hàm FIND tìm dấu phẩy thứ nhất tại ô B2 là:

=FIND(",", B2)

Hàm FIND tìm vị trí dấu phẩy thứ hai tại ô B2 là:

=FIND(",", B2, FIND(",", B2)+1)
 

Bước 2: dùng hàm MID để tách phần tên Quận

Vị trí: tên Quận sẽ nằm trong phạm vi từ sau vị trí dấu phẩy thứ 1 đến trước vị trí trước dấu phẩy thứ hai.

Hàm MID gồm 3 thành phần:

• Nội dung đoạn văn bản gốc: ô B2
• Vị trí bắt đầu tách: sau vị trí dấu phẩy thứ nhất 2 ký tự (sau dấu phẩy thứ 1 có 1 dấu cách rồi đến ký tự bắt đầu của tên Quận, như vậy là 2 ký tự)
• Độ dài ký tự cần tách: vị trí dấu phẩy thứ 2 trừ đi vị trí dấu phẩy thứ 1 trừ đi 2 ký tự nữa (1 là ký tự dấu cách sau dấu phẩy thứ nhất, 1 là không tính vị trí dấu phẩy thứ hai, chỉ tính đến trước ký tự này mà thôi)

Như vậy hàm MID viết như sau:

=MID(B2, Vị trí dấu phẩy thứ nhất + 2, Vị trí dấu phẩy thứ hai - Vị trí dấu phẩy thứ nhất - 2)

Cụ thể:

=MID(B2, FIND(",", B2)+2, FIND(",", B2, FIND(",", B2)+1) - FIND(",", B2) - 2)

Đặt công thức tại ô C2, sau đó bạn áp dụng công thức này cho toàn bộ vùng C2:C5  bằng kỹ thuật FillDown
 

Kết quả là:

Yêu cầu thứ 2: Tách tên thành phố

Để tách tên thành phố ra khỏi địa chỉ, bạn sẽ dùng hàm RIGHT như sau:

• Nội dung đoạn văn bản gốc: ô B2
• Độ dài đoạn văn bản cần tách: Toàn bộ độ dài đoạn văn bản - Vị trí dấu phẩy thứ hai - 1 (trừ thêm 1 ký tự dấu cách phía sau dấu phẩy thứ hai)
• Để xác định toàn bộ độ dài đoạn văn bản, chúng ta dùng hàm LEN tham chiếu tới ô B2
• Vị trí dấu phẩy thứ 2 đã xác định bằng hàm FIND ở trên

Khi đó ta có

=RIGHT(B2, LEN(B2) - FIND(",", B2, FIND(",", B2)+1) - 1)

Đặt công thức tại ô D2, sau đó bạn áp dụng công thức này cho toàn bộ vùng D2:D5  bằng kỹ thuật FillDown

Kết quả là:

 

Như vậy chúng ta đã hoàn thành bài tập thứ 1: tách tên Quận, thành phố ra khỏi Địa chỉ bằng hàm FIND kết hợp với các hàm MID, RIGHT.

Giải bài tập tách Năm sinh và Bộ phận ra khỏi thông tin nhân viên bằng hàm SEARCH

Trong bài tập này chúng ta có:

 

Với yêu cầu thứ 1: Tách năm sinh

dấu hiệu nhận biết chính là xác định vị trí các dấu mở ngoặc đơn, dấu đóng ngoặc đơn trong cột Thông tin nhân viên.

Bước 1: Dùng hàm SEARCH tìm vị trí các dấu này, chú ý khi viết dấu này trong hàm bạn phải đặt trong cặp dấu nháy kép

Tìm dấu mở ngoặc đơn

=SEARCH("(", A2)

Tìm dấu đóng ngoặc đơn

=SEARCH(")", A2)

Hãy chú ý cách viết nhé, bạn sẽ rất dễ nhầm lẫn nếu không phân biệt rõ cách viết các dấu ( ) khi dùng nó làm đối tượng tìm kiếm.

Bước 2: dùng hàm MID xác định đoạn text cần tách:

Năm sinh nằm sau dấu mở ngoặc đơn và nằm trước dấu đóng ngoặc đơn, do đó:

• Nội dung đoạn văn bản gốc: ô A2
• Vị trí bắt đầu tách: sau vị trí dấu mở ngoặc đơn 1 ký tự
• Độ dài ký tự cần tách: vị trí dấu đóng ngoặc đơn trừ đi vị trí dấu mở ngoặc đơn và trừ đi 1 ký tự nữa (không tính vị trí ký tự đóng ngoặc đơn nên phải trừ đi 1 ký tự)

Như vậy hàm MID viết như sau:

=MID(A2, Vị trí dấu mở ngoặc đơn +  1, Vị trí dấu đóng ngoặc đơn - Vị trí dấu mở ngoặc đơn - 1)

Cụ thể:

=MID(A2, SEARCH("(", A2)+1, SEARCH(")", A2) - SEARCH("(", A2) - 1)

Đặt công thức tại ô B2, sau đó bạn áp dụng công thức này cho toàn bộ vùng B2:B5  bằng kỹ thuật FillDown
 

Kết quả là:

 

Chú ý:

Hàm MID sẽ cho kết quả là dữ liệu ở dạng văn bản (text) cho dù đoạn văn bản đó chỉ chứa các con số. Ở dạng văn bản thì chúng ta sẽ không dùng để tính toán theo các phép tính được.

Do đó để đưa kết quả đúng là dạng Số, chúng ta cần thêm hàm VALUE lồng bên ngoài hàm MID để chuyển kết quả hàm MID về dạng Số như sau:

=VALUE(MID(...))

 

Yêu cầu thứ 2: Tách bộ phận

Để tách bộ phận, chúng ta cũng xác định vị trí dấu - bằng hàm SEARCH rồi kết hợp với hàm RIGHT để tách dựa theo phần bên phải của thông tin nhân viên:

Bước 1: Hàm SEARCH tìm vị trí dấu gạch ngang

=SEARCH("-", A2)

Bước 2: dùng hàm RIGHT để tách

=RIGHT(A2, LEN(A2) - SEARCH("-", A2) - 1)

Tại sao phải trừ đi 1 ký tự trong hàm RIGHT ở trên? Đó là vì hàm SEARCH chỉ cho chúng ta vị trí dấu gạch ngang mà thôi, nhưng ở sau dấu gạch ngang còn có ký tự dấu cách nữa, cho nên phải trừ đi ký tự này thì kết quả mới đúng.

Kết quả là:

 

Kết luận

Hy vọng rằng qua bài viết này các bạn đã có thể hiểu rõ hơn về cách sử dụng hàm FIND, hàm SEARCH vào trong công việc.

Thực tế cho thấy những hàm tìm kiếm dạng ký tự, trích lọc ký tự dù cú pháp rất đơn giản nhưng khi vận dụng vào thực tế lại rất khó, dễ nhầm lẫn. Bạn cần thực hành nhiều để hiểu rõ hơn về các nguyên tắc trích lọc này.

Nếu có bất kỳ thắc mắc gì bạn có thể góp ý, phàn hồi ngay dưới bài viết này để chúng tôi có thể giải quyết mọi thắc mắc của bạn một cách sớm nhất.

Tải file bài tập có đáp án

Các bạn có thể tải file bài tập có đáp án tại đường link bên dưới: