Hướng dẫn sử dụng hàm RANDARRAY trong Excel để lấy số ngẫu nhiên

Thông thường, bạn sẽ sử dụng hàm gì để lấy số ngẫu nhiên trong Excel? Có lẽ câu trả lời của bạn sẽ là hàm RAND hoặc hàm RANDBETWEEN. Vậy thì hãy cùng Gitiho tìm hiểu một hàm lấy số ngẫu nhiên mới và vô cùng hữu ích mang tên hàm RANDARRAY nhé.

Giới thiệu về hàm RANDARRAY

Hàm RANDARRAY là gì?

Hàm RANDARRAY trong Excel trả về một mảng số ngẫu nhiên theo kích thước (số hàng và số cột) được chỉ định. Kết quả của hàm RANDARRAY có thể là mảng số nguyên hoặc mảng số thập phân dựa vào công thức bạn viết. Kết quả này sẽ tự động thay đổi sau mỗi lần bạn nhấn Enter để tính toán trang tính.

Hiện tại, hàm RANDARRAY chỉ được cập nhật trong Excel 2019 và 365. Do đó, nếu bạn đang sử dụng các phiên bản Excel cũ hơn, đáng tiếc phải thông báo với bạn rằng bạn sẽ không thể tìm thấy hàm RANDARRAY.

Xem thêm: Hàm với dữ liệu dạng Number: Hàm lấy số ngẫu nhiên RAND và RANBETWEEN

Cú pháp hàm RANDARRAY

Hàm RANDARRAY có cú pháp như sau:

=RANDARRAY([rows],[columns],[min],[max],[whole_number])

Trong đó:

• rows - Số hàng cần trả về
• columns - Số cột cần trả về
• min - Số nhỏ nhất hàm RANDARRAY có thể trả về
• max - Số lớn nhất hàm RANDARRAY có thể trả về
• whole_number - Trả về số nguyên hay số thập phân
  • TRUE - Số nguyên
  • FALSE - Số thập phân

Tưởng chừng phức tạp nhưng cú pháp hàm RANDARRAY thực chất vô cùng dễ hiểu và rõ ràng. Nói một cách đơn giản, bạn chỉ cần xác định kích thước mảng và giới hạn phạm vi lấy số ngẫu nhiên.

Toàn bộ các tham số của hàm RANDARRAY đều là các tham số không bắt buộc. Chính vì vậy, bạn hoàn toàn có thể bỏ qua bất kỳ tham số nào trong công thức. Thậm chí khi bạn không điền tham số nào, hàm RANDARRAY vẫn sẽ hoạt động bình thường mà không gặp lỗi.

Một số lưu ý với hàm RANDARRAY

Khi sử dụng hàm RANDARRAY để lấy số ngẫu nhiên trong Excel, bạn hãy lưu ý một vài điểm sau đây nhé.

• Đảm bảo phía dưới và bên phải ô tính bạn nhập công thức hàm RANDARRAY có đủ số lượng ô tính trống cần thiết để hàm tạo mảng số. Nếu không, hàm sẽ trả về lỗi #SPILL.
• Nếu bạn bỏ qua tham số [min] hoặc [max], hàm RANDARRAY sẽ mặc định lần lượt giá trị của các tham số này là 0 và 1.
• Nếu bạn điền số thập phân vào các tham số, hàm RANDARRAY sẽ chỉ lấy phần nguyên của giá trị đã nhập (Ví dụ: 2.3 sẽ được coi là 2)
• Nếu bạn bỏ qua tất cả các tham số trong công thức, hàm RANDARRAY sẽ trả về một số ngẫu nhiên duy nhất trong khoảng từ 0 đến 1, tương tự như hàm RAND.
• Hàm RANDARRAY tự động cập nhật kết quả sau mỗi lần tính toán trang tính. Nếu bạn không muốn kết quả bị thay đổi, hãy copy toàn bộ kết quả > Paste Special > Values.

Xem thêm: Giới thiệu tính năng Paste Special hiệu quả trong đề thi MOS Excel

Cách dùng hàm RANDARRAY

Hãy cùng thực hành từ ứng dụng cơ bản nhất của hàm RANDARRAY - lấy số ngẫu nhiên trong Excel. Giả sử mình cần tạo một mảng số ngẫu nhiên 4x6 với các số nguyên trong khoảng 0 đến 50, mình sẽ sử dụng công thức hàm lấy số ngẫu nhiên như sau:

=RANDARRAY(6,4,0,50,TRUE)

Như vậy, bạn đã có một bảng số ngẫu nhiên với các số nguyên trong khoảng từ 0 đến 50. Tuy nhiên, hãy lưu ý rằng hàm RANDARRAY chỉ tạo mảng số ngẫu nhiên chứ không phải một mảng số độc nhất. Vì vậy, bạn có thể thấy sẽ có một vài số bị lặp lại trong bảng.

Các ứng dụng của hàm RANDARRAY

Nếu như chỉ cần sử dụng một hàm lấy số ngẫu nhiên, có lẽ RANDARRAY sẽ không phải lựa chọn hàng đầu của bạn. Tuy nhiên, đừng vội đánh giá thấp sức mạnh của hàm RANDARRAY bạn nhé, bởi nó có thể kết hợp với các hàm Excel khác để tạo nên các công thức vô cùng mạnh mẽ đấy. Hãy cùng mình tìm hiểu các ứng dụng của hàm RANDARRAY nhé.

Sắp xếp danh sách trong Excel theo thứ tự ngẫu nhiên

Nếu như bạn đã chán với cách sắp xếp danh sách trong Excel theo thứ tự tăng dần hoặc giảm dần, hãy thử sắp xếp chúng theo thứ tự ngẫu nhiên với hàm RANDARRAY nhé.

Công thức bạn cần là:

=SORTBY(n,RANDARRAY(COUNTA(n)))

Trong đó: n - Phạm vi dữ liệu cần sắp xếp

Đầu tiên, hàm COUNTA sẽ đếm các ô không trống trong danh sách để xác định kích thước của mảng dữ liệu hàm RANDARRAY cần trả về. Sau đó, hàm SORTBY sẽ sử dụng kết quả đó để sắp xếp dữ liệu.

Giả sử mình có một bảng điểm như trong hình dưới đây:

Công thức sắp xếp dữ liệu theo thứ tự ngẫu nhiên như sau:

=SORTBY(A2:B15,RANDARRAY(COUNTA(B2:B15)))

Tạo dãy số ngẫu nhiên không trùng lặp

Mặc dù Excel chưa có một hàm lấy số ngẫu nhiên nào có khả năng tạo ra một dãy số không trùng lặp, bạn hoàn toàn có thể làm được điều này với hàm RANDARRAY.

Công thức bạn cần để tạo dãy số ngẫu nhiên không trùng lặp với n số là:

=INDEX(UNIQUE(RANDARRAY(n^2,1,min,max,TRUE)),SEQUENCE(n))

Trong đó:

• n - Số giá trị cần tạo
• min - Giá trị nhỏ nhất hàm RANDARRAY có thể trả về
• max - Giá trị lớn nhất hàm RANDARRAY có thể trả về

Đầu tiên, hàm RANDARRAY sẽ tạo ra dãy n^2 số ngẫu nhiên trong khoảng 0 đến 50, sau đó hàm UNIQUE sẽ lọc ra các giá trị duy nhất trong dãy số này. Vì hàm RANDARRAY tạo ra dãy số ngẫu nhiên nhưng khổng phải duy nhất, nên bạn sẽ cần lấy nhiều hơn số giá trị cần thiết để hàm UNIQUE có thể lọc ra các giá trị không trùng.

Từ dãy số đã lọc trùng của hàm UNIQUE, hàm INDEX sẽ chọn ra các giá trị đầu tiên. Số lượng giá trị hàm INDEX sẽ trả về phụ thuộc vào hàm SEQUENCE. Với tham số n của hàm SEQUENCE, hàm INDEX sẽ trả về n giá trị đầu tiên trong dãy số của hàm UNIQUE.

Giả sử mình cần tạo một dãy 10 số ngẫu nhiên không trùng lặp với các số trong khoảng 0 đến 50, mình sẽ sử dụng công thức dưới đây:

=INDEX(UNIQUE(RANDARRAY(10^2,1,0,50,TRUE)),SEQUENCE(10))

Xem thêm: Cách tạo dãy số ngẫu nhiên không trùng lặp trong Excel

Tạo mật khẩu từ các ký tự ngẫu nhiên

Khi kết hợp với các hàm văn bản trong Excel, sức mạnh của hàm RANDARRAY sẽ được nâng tầm. Một trong những ứng dụng này là tạo mật khẩu từ các ký tự ngẫu nhiên. Bạn sẽ cần đến công thức như sau:

=TEXTJOIN("",TRUE,CHAR(RANDARRAY(n,1,33,125)))

Trong đó: n - Số ký tự cần để tạo mật khẩu

Để lấy ra n ký tự ngẫu nhiên bao gồm cả chữ viết thường, chữ viết hoa, số và ít nhất một ký tự đặc biệt, chúng ta sẽ sử dụng hàm CHAR lồng RANDARRAY. Sau đó, hàm TEXTJOIN sẽ ghép các ký tự này lại với nhau để hoàn thiện mật khẩu.

Giả sử bạn cần tạo một mật khẩu dài 10 ký tự, bạn sẽ điền công thức dưới đây:

=TEXTJOIN("",TRUE,CHAR(RANDARRAY(10,1,33,125)))

Xem thêm: Hướng dẫn sử dụng hàm TEXTJOIN làm hàm đảo ngược chuỗi trong Excel

Tổng kết

Vậy là chúng ta đã làm quen với hàm RANDARRAY - một hàm lấy số ngẫu nhiên mới trong Excel. Hy vọng kiến thức trong bài viết đã giúp bạn hiểu được cách dùng và các ứng dụng hữu ích của hàm RANDARRAY trong Excel. Có thể khi bắt tay vào làm việc, bạn sẽ nhận thấy hàm RANDARRAY có khả năng làm được rất nhiều thứ ngoài các ứng dụng chúng ta đã tìm hiểu trong bài viết ngày hôm nay.

Để học về các hàm Excel, bạn hãy tham khảo ngay khóa học Tuyệt đỉnh Excel chuyên sâu về kỹ năng sử dụng hàm Excel tại đây nhé. Nếu bạn là người đã có sẵn nền tảng Excel cơ bản, đây chính là khóa học dành cho bạn. Không chỉ được cung cấp kiến thức về các hàm Excel nâng cao, bạn cũng sẽ được rèn luyện kỹ năng quy trình hóa các thao tác xử lý dữ liệu để tối ưu hiệu quả làm việc trên trang tính. Cùng tham gia lớp học ngay với chúng mình nhé!

Gitiho xin cảm ơn bạn đọc và chúc bạn thành công!