Dear teacher làm ví dụ save dưới ng file excel thông thường rồi mở file lại

Cảm ơn bạn đã góp ý. Phần này mình sẽ chuẩn bị thêm tài liệu. Về code lưu file, mở file thì chúng ta hoàn toàn có thể dùng theo các đoạn code mẫu:

Code lưu file:

Sub Luu_Workbook_FileDialogSaveAs()
     'Mở cửa sổ FileDialog SaveAs
     With Application.FileDialog(msoFileDialogSaveAs)
           .FilterIndex = 2
          .Show
          If .SelectedItems.Count > 0 Then     'Có file được chọn
                ActiveWorkbook.SaveAs Filename:=.SelectedItems(1), _
                    FileFormat:=xlOpenXMLWorkbookMacroEnabled
          Else     'Các trường hợp khác không có file được chọn
                 MsgBox ("No File Selected")
          End If
      End With
End Sub

Code mở file:

Sub Open_Single_File()
     'Khai báo các biến sử dụng
     Dim dk_Ten_tieu_de As String     'Tên tiêu đề cửa sổ Workbook Open
     Dim dk_Loc_LoaiFile As String    'Lọc các loại file có trong cửa sổ Workbook Open 
     Dim dk_Loc_Index As Integer      'Thứ tự lọc mặc định
     Dim kq_File_duoc_chon As String  'File được chọn
          dk_Loc_LoaiFile = "Excel Files (*.xls*),*.xls," & "CSV Files (*.csv),*.csv,"
          dk_Loc_Index = 1
          dk_Ten_tieu_de = "Select Your Input File of Choice"
     'Mở cửa sổ Workbook Open
     kq_File_duoc_chon = Application.GetOpenFilename _
          (FileFilter:=dk_Loc_LoaiFile, _
           FilterIndex:=dk_Loc_Index, _
           Title:=dk_Ten_tieu_de)
     'Các trường hợp không thành công
     'Trường hợp 1: Không có file được chọn
     If kq_File_duoc_chon = "" Then
          MsgBox ("Khong co file duoc chon")
          Exit Sub
     'Trường hợp 2. Bấm vào nút Cancel
     ElseIf kq_File_duoc_chon = "False" Then
          MsgBox ("Ban da bam lenh Huy thao tac")
          Exit Sub
     End If
     'Trường hợp thành công: Mở file được chọn
     Workbooks.Open kq_File_duoc_chon
End Sub