xin phép được hỏi là tôi muốn tạo listview có 20 ̣t nhưng chỉ thể

Bạn có thể tham khảo đoạn code dưới đây:
1. Đoạn code tải listview vào userform
Private Sub LoadListView()
'Gán các biến
Dim wksSource As Worksheet
Dim rngData As Range
Dim rngCell As Range
Dim LstItem As ListItem
Dim RowCount As Long
Dim ColCount As Long
Dim i As Long
Dim j As Long

'Thiết lập biến workbook (đổi tên sheet khác theo thực tế sử dụng)
Set wksSource = Worksheets("Sheet1")

'Thiết lập biến Range là vùng bảng tính từ ô A1 (đổi vùng khác theo thực tế sử dụng)
Set rngData = wksSource.Range("A1").CurrentRegion

'Thêm header cho bảng, chỉnh lại độ rộng các cột
For Each rngCell In rngData.Rows(1).Cells
Me.ListView1.ColumnHeaders.Add Text:=rngCell.Value, Width:=90
Next rngCell

'Đếm số dòng trong bảng
RowCount = rngData.Rows.Count

'Đếm số cột trong bảng
ColCount = rngData.Columns.Count

'Tải bảng vào Listview theo vòng lặp gồm cả dòng và cột
For i = 2 To RowCount
Set LstItem = Me.ListView1.ListItems.Add(Text:=rngData(i, 1).Value)
For j = 2 To ColCount
LstItem.ListSubItems.Add Text:=rngData(i, j).Value
Next j
Next i

End Sub

2. Đoạn code khi kích hoạt UserForm, sẽ chạy lệnh để cập nhật Listview:
Private Sub UserForm_Activate()

'Set a reference to Microsoft Windows Common Controls by
'using Tools > References in the Visual Basic Editor (Alt+F11)

'Set some of the properties for the ListView
With Me.ListView1
.Gridlines = True
.HideColumnHeaders = False
.View = lvwReport
End With

'Call the sub to fill the ListView
Call LoadListView

End Sub

Bạn đưa cả 2 đoạn code trên vào trong phần viết code của UserForm nhé.