Em đang thực hành gộp dữ liệu nhiều file vào 1 file lỗi này là bị gì vậy

Chào bạn bạn xem kết quả code nhé

Option Explicit
Sub Luu_DuLieu()
'Thu muc chon file
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False    'cho phep chon nhieu file
        If .Show = -1 Then      'co thuc hien chon noi dung
            Dim DuongDan As String     'dai dien cho duong dan
                DuongDan = .SelectedItems(1) & "\"
            Dim TenFile As String       'Dai dien cho ten file duoc chon
                TenFile = "*BangLuong*.xls*"
            Dim File_duoc_mo As String
                File_duoc_mo = Dir(DuongDan & TenFile)
            
            Do While File_duoc_mo <> ""
                'Xet file duoc chon
                Dim wb_KQ As Workbook   'Bien workbook ket qua (Bang luong tong hop)
                Dim wb_1 As Workbook     'Bien workbook duoc chon tu thu muc (Tung file bang luong chi tiet)
        
                Set wb_KQ = ThisWorkbook
                Set wb_1 = Workbooks.Open(Filename:=DuongDan & File_duoc_mo)
            
                'B1: xac dinh dong cuoi bang tong hop (Bang luong tong hop)
                Dim DongCuoi_KQ As Long
                DongCuoi_KQ = wb_KQ.Sheets("Data_TienLuong").Range("A" & Rows.Count).End(xlUp).Row
                
                'B2: xac dinh dong dau va dong cuoi bang chi tiet (Tung file bang luong chi tiet)
                Dim DongDau_CT As Long
                    DongDau_CT = 8
                    
                Dim DongCuoi_CT As Long
                    DongCuoi_CT = wb_1.Sheets(1).Range("F" & Rows.Count).End(xlUp).Row
                    
                'B3: xac dinh khoang cach
                Dim KhoangCach As Long
                KhoangCach = DongCuoi_CT - DongDau_CT + 1
                
                'B4: luu
                wb_KQ.Sheets("Data_TienLuong").Range("A" & DongCuoi_KQ + 1 & ":BM" & DongCuoi_KQ + KhoangCach).Value = _
                    wb_1.Sheets(1).Range("A" & DongDau_CT & ":BM" & DongCuoi_CT).Value
                
                'B5: Dong file noi dung
                wb_1.Close SaveChanges:=False
            
            'Xac dinh lai file khac duoc mo
                File_duoc_mo = Dir
            Loop
        End If
    End With
End Sub

Em đang viết theo hàm For - Next ạ. Và so sánh với code trong bào giảng lại không phát hiện lỗi sai. giờ em thực hiện chạy lại lệnh nó ra như cửa sổ như chỗ con trõ chuột trong hình ạ.

Chào bạn bạn đẩy file của bạn lên để gitiho kiểm tra được không?